-- maak een briefje + kaartjes naar alle eMail's uit eMail_adres 
-- eMail bestand
-- bestand eerste regel <naam evenement>,<ompouledatum>
-- bestand geeft <Kaartje>,<Brief>,<Orgnaam>,<eMail> (csv file)  
sequence eMail_adres
-- beleidend schrijven  ( $ vult in :Orgnaam , voor/op , ompoule datum )
sequence briefje 
-- geef 'subject' waar over gaat deze eMail  (Naam evenement)
sequence subject  -- strip cr anders krijg je een multi mine ! 
-- zet file_path als er een bestand moet worden mee gestuurd       
sequence file_path ={}--current_dir()&'\\'  -- Moet voor MAPI
sequence file_attach
sequence OPVOOR,OMPOULE

include readf.e 
--include Oe_post.ew -- MAPI
include makemail.e 

--  calling program mkabr <begeleidendschrijven> <eMails>
subject=command_line()
-- eerste parameter is de aanroep of peu* of mkabr(.exe)
-- tweede parameter is mkabr.exw of <begeleidendschrijven>
-- derde  parameter is <begeleidendschrijven> of <eMails>
-- vierde parameter is <eMails> of leeg (bestaat niet)
if length(subject)<3
then puts(1,"Using mkabr begeleidendschrijven_file eMails_file\n") abort(1)
else briefje=subject[length(subject)-1]
     eMail_adres=subject[length(subject)]
end if
-- lees brief (begeleidend schrijven)
integer  brief_file=open(briefje,"r"),i
sequence brief={},line,org_naam,mails 
if brief_file>2
then  line=gets(brief_file)
      while sequence(line) do
         brief&=line
         line=gets(brief_file)
      end while
      close(brief_file)
else  puts(1,"Error begeleidend schrijven is zoek\n")
      abort(1)
end if             
-- brief gelezen

-- lees adressen uit email.lst
brief_file=open(eMail_adres,"r")
if brief_file<3
then puts(1,"Error eMails zijn zoek\n") abort(1)
end if

-- eerste regel is aanhef eMail o.t.w. het onderwerp .
line   =readf(brief_file,',')
subject=line[1]    -- onderwerp
OPVOOR =line[2]    -- op / voor ompoule datum
OMPOULE=line[3]    -- ompoule datum 
i=find('$',brief)  -- skip Org_naam
i=find('$',brief[i+1..])+i
brief=brief[1..i-1]&OPVOOR&brief[i+1..]    
i=find('$',brief[i+1..])+i
brief=brief[1..i-1]&OMPOULE&brief[i+1..]    
-- logon MAPI
if Logon() then puts(1,"Error on log on\n") abort(0) end if
-- file's en eMails
line   =readf(brief_file,',')
while sequence(line) and length(line) do 
 -- een juist eMail groep bestaat uit <bijlage Kaartje>,<bijlage brief>,<orgnaam>,<eMail>
 if length(line)=4 then 
   -- je moet de gehele path / file naam geven anders gaat het fout ! 
   file_attach={file_path&line[1],file_path&line[2]} 
   org_naam=line[3]  -- Org naam
   mails   =line[4]  -- eMail adres
   puts(1,"send to: "&mails&'\n')
   i=find('$',brief) -- vul in de Org naam
   line=brief[1..i-1]&org_naam&brief[i+1..]    
   if length(file_attach) -- check dat er attach file's zijn .
   then i=sendfile(mails,subject,line,file_attach)
   else puts(1,"Error , no file's\n")
   end if 
   if i 
   then printf(1,"Error = %d at eMail = %s\n",{i,mails}) abort(1) 
   else puts(1,"eMail is send\n")
   end if
 else
   puts(1,"Error in mail file\n")  
 end if  
 line=readf(brief_file,',')
end while
close(brief_file)
-- logoff MAPI
if Logoff() then puts(1,"Error on log off\n") abort(0) end if
-- einde